2.1.7 Výpočet tlaku plynu ze stavových rovnic

2 Reálné chování tekutin 2.1 Reálné plyny a kapaliny

2.1.6 Odhad druhého viriálního koeficientu 2.1.8 * Výpočet kritického ...

2.1.7 Výpočet tlaku plynu ze stavových rovnic

Určete tlak, který vykazuje 1 mol amoniaku v nádobě o objemu V = 0,34 dm³ při teplotě 325 °C. Kritický tlak amoniaku je p_c = 11,35 MPa, kritická teplota T_c = 405,5 K. Výpočet proveďte s použitím:

• a) stavové rovnice ideálního plynu,

• b) van der Waalsovy rovnice,

• c) Redlichovy-Kwongovy rovnice.

↓

Výsledek
Postup
Řešení
Maple

Výsledek

a) p(id.) = 14,63 MPa b) p(v.d.W.) = 12,76 MPa c) p(R.K.) = 12,99 MPa

Postup

Z podmínek v kritickém bodě vypočítejte hodnoty konstant stavové rovnice a po jejich dosazení vypočtěte tlak.

Řešení

a) Ze stavové rovnice ideálního plynu vyplývá

$displaymath$

b) Podle van der Waalsovy rovnice platí

$displaymath$

Hodnoty konstant a, b můžeme vypočítat podle vztahů

$displaymath$

na základě kritických veličin. Získali bychom a = 0,4225 m⁶ mol⁻² Pa, b = 3,713^.10⁻⁵ m³/mol. Dosazením získáme tlak

$displaymath$

c) Redlichova-Kwongova rovnice udává pro tlak vztah

$displaymath$

Konstanty a,b lze určit s použitím kritické teploty a kritického tlaku podle vztahů

$displaymath$

takže

$displaymath$

Dosazením těchto hodnot do stavové rovnice získáme

$displaymath$

Maple

> restart;

Neprve provedeme výpočet pro ideální plyn

> R:=8.314;

> T:=325+273.15;

> Vm:=0.34*10^(-3);

> p:=R*T/Vm;

Dále použijeme van der Waalsovu stavovou rovnici

> restart;

> p:=R*T/(Vm-b)-a/Vm^2;

Pro určení konstant nejprve vypočteme první dvě derivace tlaku podle objemu

> d1:=diff(p,Vm);

> d2:=diff(d1,Vm);

V kritickém bodě platí následující tři rovnice: 1. a 2. derivace jsou nulové a tlak je roven kritickému tlaku

> r1:=subs(Vm=Vc,T=Tc,d1=0);

> r2:=subs(Vm=Vc,T=Tc,d2=0);

> r3:=subs(Vm=Vc,T=Tc,p=pc);

Konstanty stavové rovnice a kritický objem dostaneme řešením soustavy předchozích tří rovnic

> reseni:=solve({r1,r2,r3},{a,b,Vc});

a provedeme tedy jejich dosazení

> assign(reseni);

Nyní již mužeme z kritických veličin konstanty vypočítat

> R:=8.314;

> Tc:=405.5;

> pc:=11.35*10^6;

> evalf(a);

> evalf(b);

Dosazením molárního objemu a teploty pak získáme požadovaný tlak

> T:=325+273.15;

> Vm:=0.34*10^(-3);

> p;

Analogicky můžeme postupovat pro Redlichovu-Kwongovu rovnici

> restart;

> p:=R*T/(Vm-b)-a/(sqrt(T)*Vm*(Vm+b));

Pro určení konstant opět vypočteme první dvě derivace tlaku podle objemu

> d1:=diff(p,Vm);

> d2:=diff(d1,Vm);

V kritickém bodě platí následující tři rovnice: 1. a 2. derivace jsou nulové a tlak je roven kritickému tlaku

> r1:=subs(Vm=Vc,T=Tc,d1=0);

> r2:=subs(Vm=Vc,T=Tc,d2=0);

> r3:=subs(Vm=Vc,T=Tc,p=pc);

Nyní se pokusíme nalézt řešení

> reseni:=solve({r1,r2,r3},{a,b,Vc});

Je vidět, že tentokrát soustava vede ke kubické rovnici, která má obecně tři řešení.

> allvalues(reseni);

Pouze první řešení je fyzikálně opodstatněné (neobsahuje komplexní čísla). Provedeme tedy jeho dosazení

> assign(%[1]);

a vyčíslime vyjádření konstant pomocí kritických veličin

> evalf(a);

> evalf(b);

Na závěr opět určíme jejich hodnoty

> R:=8.314;

> Tc:=405.5;

> pc:=11.35*10^6;

> evalf(a);

> evalf(b);

a osazením molárního objemu a teploty získáme požadovaný tlak

> T:=325+273.15;

> Vm:=0.34*10^(-3);

> evalf(p);

>